1000 CALL PRY
1010 CALL HEX
1020 SUB PRY
1030 IMAGE #####       ###   ###   ###   ###   ###   ###   ###  ###      #####
1040 OPEN #1,"45.",OUTPUT
1050 INPUT "ADDRESS: ";X
1060 CALL PEEK(X,A,B,C,D,E,F,G,H)
1070 PRINT #1,USING 1030,X,A,B,C,D,E,F,G,H,X+7
1080 CALL KEY(J,K)
1090 IF K<>0 AND J=232 THEN X=X+8:GOTO 1060
1100 IF K<>0 AND J=233 THEN X=X-8:GOTO 1060
1110 IF K<>0 AND J=254 THEN CLOSE #1:GOTO 1040
1120 GOTO 1080
1130 SUBEND
1135 !
1140 SUB HEX
1150 ON ERROR 1580
1160 DATA A,B,C,D,E,F
1170 INPUT "HEX~DEC: ";Z$
1180 IF Z$=""THEN 1280
1190 Y=LEN(Z$):G=0
1200 FOR X=1 TO Y
1210 X$(X)=SEG$(Z$,X,1)
1220 NEXT X
1230 FOR X=1 TO Y
1240 IF NOT NUMERIC(X$(X))THEN W(X)=ASC(X$(X))-55 ELSE W(X)=VAL(X$(X))
1250 G=G+(W(X)*(16^(Y-X)))
1260 NEXT X:
1270 PRINT TAB(2);Z$;"   ";G:PAUSE:GOTO 1170
1275 !
1280 INPUT "DEC~HEX: ";G$:IF G$=""THEN 1390
1290 A$="":Z=VAL(G$)
1300 Z$=STR$(((Z/16)-INT(Z/16))*16):GOSUB 1360
1310 A$=Z$&A$
1320 Z=INT(Z/16)
1330 IF Z>15 THEN 1300 ELSE Z$=STR$(Z):GOSUB 1360
1340 A$=Z$&A$
1350 PRINT TAB(2);G$;"   ";A$:PAUSE:GOTO 1280
1360 RESTORE:FOR X=10 TO 15
1370 READ B$:IF X=VAL(Z$)THEN Z$=B$:RETURN
1380 NEXT X:RETURN
1385 !
1390 INPUT "DEC~BINARY: ";F$:IF F$=""THEN 1450
1400 F=VAL(F$):J$=""
1410 G=F/2:IF G=.5 THEN J$="1"&J$:GOTO 1440
1420 H=INT(G):I=(G-H)*2:I$=STR$(I):J$=I$&J$
1430 IF H>0 THEN F=H:GOTO 1410
1440 PRINT TAB(2);F$;"   ";J$:PAUSE:GOTO 1390
1445 !
1450 INPUT "BINARY~DEC: ";K$:IF K$=""THEN 1530
1460 X=LEN(K$):N=0
1470 FOR Y=1 TO X
1480 L$=SEG$(K$,Y,1):L=VAL(L$)
1490 M=L*2^(X-Y)
1500 N=M+N
1510 NEXT Y
1520 PRINT TAB(2);K$;"   ";N:PAUSE:GOTO 1450
1525 !
1530 INPUT "DEC~16-bit HEX ADDR: ";DH$:IF DH$=""THEN 1550 ELSE DH=VAL(DH$)
1540 HI=INT(DH/256):LO=DH-(HI*256):PRINT DH;TAB(9);HI;LO:PAUSE:GOTO 1530
1545 !
1550 INPUT "16-bit addr~Dec,H]i byte: ";DE$:IF DE$=""THEN 1170 ELSE DE=VAL(DE$)
1560 INPUT "16-bit addr~Dec,L]o byte: ";DF
1570 DG=(DE*256)+DF:DISPLAY ERASE ALL,DE$;DF;DG:PAUSE:GOTO 1550
1575 !
1580 CALL ERR(E0,E1,E2,E3)
1590 IF E0=12 AND E3=270 THEN ON ERROR 1580:RETURN NEXT
1600 IF E0=12 AND E3=290 THEN ON ERROR 1580:RETURN NEXT
1610 PRINT "UNEXPECTED ERROR ";E0;E1;E2;E3:PAUSE
1620 SUBEND