0 'PBBS.BA BY DICK ROUX N1AED VERSION 2.0 08/21/86 CLUB 100 LIBRARY - 415/939-1246 BBS, 937-5039 NEWSLETTER, 932-8856 VOICE
1 'Program modified by Jim Jackson, WA6DDM, Daly City
2 REM modified version 12/23/86 for CTRL-E disconnect
10 CLEAR1000:MAXFILES=6:LC$="":MD=0:MM=0:UL=0:S=0:MW=0:MF=0
15 FL=0:MR=0:RQ=0:RD=0:C=0:L=0:MS=0:U=0:CR$="":B=0:M=0:CK=0:CK$="ON ":CALL16969:CA$="WA6DDM":NA$="Jim":T$="Daly City
20 BE$="MAIL FOR: ":OPEN"ERRLOG.DO"FORAPPENDAS1:CLOSE1
25 GOSUB880
30 MM=0:MS=0:ONERRORGOTO45:OPEN"MESLOG.DO"FORINPUTAS4
35 LINEINPUT#4,I$:IFLEN(I$)=>3THENMS=MS+1:IFI$=CA$THENMM=MM+1
40 IFEOF(4)THENCLOSE4:GOTO50ELSE35
45 IFERR=52THENOPEN"MESLOG.DO"FORAPPENDAS4:PRINT#4,CR$:CLOSE4
50 ONCOMGOSUB125:ONERRORGOTO410
55 IFUTHENGOSUB870:U=0:GOSUB90ELSEGOSUB90
60 COMON
65 E$=INKEY$:GOSUB70:GOTO75
70 DA$=RIGHT$(DATE$,2)+LEFT$(DATE$,2)+MID$(DATE$,4,2):TI$=LEFT$(TIME$,2)+MID$(TIME$,4,2):RETURN
75 IFE$=""THEN65
80 ONINSTR("EPRSGKBMCTFA",E$)GOTO315,330,355,690,380,580,865,915,935,950,930,945
85 ONINSTR("eprsgkbmctfa",E$)GOTO315,330,355,690,380,580,865,915,935,950,930,945:GOTO65
90 IFCTHENRETURNELSECLS
95 PRINT"MAILBOX ACTIVE - WAITING "MM"/"MS" Msgs":PRINTFRE(0)" BYTES FREE "MR"CONNECTS TODAY
100 IFLEN(LC$)THENPRINT"Last User: "LC$ELSEPRINT
105 IFB=0THENBB$="OFF"ELSEBB$="ON
110 IFM=0THENMM$="OFF"ELSEMM$="ON
115 PRINT"
rint Msgs ead Msgs xit":PRINT"end Msg o Online ill Msgs
120 PRINT"eacon "BB$" onitor "MM$" ime":PRINT"onok "CK$" iles nnouncement":PRINT"Enter choice:";:RETURN
125 IFEOF(2)THENCLOSE2:OPEN"COM:37N1E"FORINPUTAS2:IFS=0THEN160ELSEPRINT#4,Z$:Z$="":S=0:FL=1:FORI=1TO500:NEXT:COMON:GOSUB625:GOSUB655:GOTO160
130 C$=INPUT$(1,2):PRINTC$;:IFC$=CHR$(10)THENRETURN
135 IFC$=CHR$(13)THEN145
140 Z$=Z$+C$:IFLEN(Z$)=>78THEN145ELSERETURN
145 IFNOTCTHEN170
150 FG=INSTR(Z$,"*** conn"):IFFGTHENRQ$=MID$(Z$,20+FG,8):RQ=1:GOTO160
155 IFCTHEN185
160 IFRD=0ANDS=0ANDRQANDCTHENO$=RQ$+" Just Tried to Connect":GOSUB430:RQ=0
165 Z$="":RETURN
170 R=INSTR(Z$,"*** CON"):IFNOTLANDR>0THENCLS:C=-1:GOSUB845:GOSUB890ELSE160
175 IFFL=0THENGOSUB435
180 COMSTOP:GOSUB635:COMON:IFMFTHEN160ELSEGOSUB525:GOSUB655:GOTO160
185 IFINSTR(Z$,"*** DIS")THENC=0:GOSUB900:GOTO305
190 IFINSTR(Z$,"retry")THEN165
195 IFSTHEN290
200 IFMFTHEN265
205 IFLTHEN160
210 IFZ$<>CR$THENZ=ASC(LEFT$(Z$,1)):IFZ>96ANDZ<123THENGOSUB855:Z$=ZX$:ZX$="
215 IFLEN(Z$)>1THEN265
220 IFZ$="T"THEN495
225 IFZ$="R"THENGOSUB545:GOSUB655:GOTO160
230 IFZ$="H"THENGOSUB725:GOSUB655:GOTO160
235 IFZ$="I"THENGOSUB760:GOSUB655:GOTO160
240 IFZ$="B"THENGOSUB670:GOSUB300:GOSUB895:GOSUB835:GOTO160
245 IFZ$="K"THENMD=1:O$="*** YOUR MESSAGE(S) WILL BE KILLED ***":GOSUB430:GOSUB655:GOTO160
250 IFZ$="S"ORZ$="s"THENGOSUB745:GOSUB655:GOTO160
255 IFZ$="u"ORZ$="U"THENGOSUB955:GOSUB655:GOSUB160
260 IFZ$<>CR$THENO$="*** NON FUNCTIONAL CMD ***":GOSUB430:GOSUB655:GOTO160
265 IFLEFT$(Z$,1)="S"ANDMID$(Z$,2,1)=" "ANDINSTR(Z$,"<")=0THEN595:COMSTOP
270 IFLEFT$(Z$,1)="S"ANDMID$(Z$,3,1)=" "THEN600:COMSTOP
275 IFLEFT$(Z$,1)="S"ANDMID$(Z$,2,2)=" "THEN600:COMSTOP
280 IFZ$<>CR$THENGOSUB855:Z$=ZX$:ZX$="":IFZ$="R ALL"THENZA$="ALL":MW=1:GOSUB550:MW=0:GOSUB655:GOTO160
285 IFZ$<>CR$THENO$="*** WHAT?...Type elp if you need it":GOSUB430:GOSUB655
290 IFSTHENPRINT#4,Z$
295 GOTO160
300 O$=ZC$+" de "+CA$+": 73 ,CUL":GOSUB430:RETURN
305 COMSTOP:GOSUB840:IFSTHENCLOSE4:S=0:GOSUB775ELSEGOSUB775:GOSUB845:GOSUB670:IFBTHENO$="BT "+BT$:GOSUB430
310 FL=0:L=0:MF=0:MR=MR+1:RD=0:GOSUB160:GOSUB720:IFMDTHEN585ELSEGOSUB905:GOSUB670:GOSUB320:GOTO55
315 COMOFF:CLOSE:GOSUB320:GOTO325
320 DATE$=LEFT$(DATE$,6)+"86":RETURN
325 MENU
330 COMSTOP:CLS:PRINT:INPUT"CHECK PRINTER - PRESS ENTER.. ";X$:CLS:INPUT"Print Your Mail";ZE$
335 IFZE$="N"ORZE$="n"THENINPUT"Print Whose";ZC$ELSEZC$=CA$
340 OPENZC$+".DO"FORINPUTAS3:OPEN"LPT:"FOROUTPUTAS4
345 LINEINPUT#3,C$:IFEOF(3)THENCLOSE3,4:GOTO55
350 FORI=1TO250:NEXT:PRINTC$:PRINT#4,C$:GOTO345
355 COMSTOP:CLS:ONERRORGOTO375:MS=0:INPUT"Read Your Mail";ZE$:IFZE$="N"ORZE$="n"THENINPUT"Read Whose";ZC$ELSEZC$=CA$
360 OPENZC$+".DO"FORINPUTAS3
365 LINEINPUT#3,C$:IFEOF(3)THENCLOSE3:PRINTCR$:PRINT"*** END OF MESSAGES ":FORI=1TO1000:NEXT:GOTO30
370 FORI=1TO500:NEXT:PRINTC$:GOTO365
375 IFERR=52THENPRINT"*** NO MESSAGES":GOSUB670:RESUME30
380 CLS:L=-1:PRINT"*** ONLINE *** ":PRINT"^E To cmd:":PRINT" to Return
385 E$=INKEY$:IFE$=""THEN385
390 IFE$=CHR$(27)THENL=0:Z$="":IFCTHENGOSUB655:GOTO55ELSE55
395 IFE$=CHR$(8)THENPRINTCHR$(8)CHR$(32);
400 PRINT#1,E$;:IFE$=CHR$(13)THENPRINTE$ELSEPRINTE$;
405 GOTO385
410 CLOSE:BEEP:OPEN"ERRLOG.DO"FORAPPENDAS6:PRINT#6,"ERROR "ERR" IN LINE "ERL" WHILE "ZC$" WAS ON AT "TI$" ON "DA$
415 IFCANDERR=57THENCLOSE6:S=0:Z$="":O$="*** SORRY, CAN'T DO IT, RAN OUT OF FILE SPACE !!! ***":GOSUB880:GOSUB430:MF=0:RESUME655
420 IFCANDERR=7THENCLOSE6:CLOSE4:S=0:Z$="":O$="*** SORRY, CAN'T DO IT, RAN OUT OF MEMORY !!! ***":GOSUB880:GOSUB430:MF=0:RESUME655
425 IFCANDERR=52THENCLOSE6:RD=0:MW=0:Z$="":O$="*** NONE FOUND":GOSUB880:GOSUB430:RESUME160ELSECLOSE6:Z$="":RESUME25
430 FORX=1TOLEN(O$):S$=MID$(O$,X,1):FORI=1TO3:NEXT:PRINT#1,S$;:PRINTS$;:NEXT:PRINT#1,CHR$(13);:PRINT:RETURN
435 IFMID$(Z$,21+R,1)="-"THENZC$=MID$(Z$,17+R,4):GOTO460
440 IFMID$(Z$,21+R,1)=" "THENZC$=MID$(Z$,17+R,4):GOTO460
445 IFMID$(Z$,22+R,1)="-"THENZC$=MID$(Z$,17+R,5):GOTO460
450 IFMID$(Z$,22+R,1)=" "THENZC$=MID$(Z$,17+R,5):GOTO460
455 ZC$=MID$(Z$,17+R,6)
460 RESTORE
465 READZF$,N$,MF:IFINSTR(ZF$,ZC$)THENRETURN
470 IFZF$="END"THENN$=ZC$:RETURN
475 GOTO465
480 DATA "WA6DDM","Jim MBX SYSOP",0,"N6IMS","Bill",0,"WA6DQP","Greg",0,"WA6YTD","Darryl",0,"WB9LOZ","Larry",0,"K9AT","Bill",0
485 DATA "WB6BMD","Alan",0,"WA6VKJ","Lee",0,"N6HZQ","Bill",0,"W6CRL","Dan",0:DATA "K6TP","Bob",0,"W6EGU","Bob",0,"KG6TP","Bob",0
490 DATA "W6PW","SFRC SYSOP:(W6PW-3) ",0,"WA6SWK","Art",0,"WB6UZO","Sam",0:DATA "END","END",0
495 PG=VAL(LEFT$(TIME$,2)):IFPG>24ANDPG<9THENO$="Sorry...Paging is disabled until after 9 A.M. >":GOSUB430:GOSUB660:GOTO160
500 CLS:O$="Paging "+NA$+"...(for about 30 Sec.) >":GOSUB430:PRINT:PRINTZC$" Wants to Chat...":PRINT:PRINT"hit to go online
505 FORI=1TO175:FORP=1TO10:NEXT:BEEP:E$=INKEY$
510 IFE$="G"ORE$="g"THENO$=NA$+" is at the keyboard...Standby! >":GOSUB430:COMON:GOTO380
515 NEXT:O$="Guess "+NA$+" is not around...Sorry":GOSUB430:O$="Feel free to leave "+NA$+" a message...73 & TNX >":GOSUB430
520 GOSUB660:GOTO160
525 ONERRORGOTO535:O$="*** CHECKING MAIL...":GOSUB430:OPENZC$+".DO"FORINPUTAS5:O$="*** YOU HAVE MAIL *** HIT 'R' TO READ
530 ONERRORGOTO410:GOSUB430:MW=1:CLOSE5:RETURN
535 IFERR=52THENO$="*** SORRY..NO MAIL":RESUME540
540 GOSUB430:ONERRORGOTO410:RETURN
545 ZA$=ZC$
550 IFMW=0THENO$="*** SORRY...NO MAIL":GOSUB430:RETURNELSERD=1:OPENZA$+".DO"FORINPUTAS5
555 LINEINPUT#5,ZD$
560 O$=CR$:GOSUB430:LINEINPUT#5,O$:DB$=LEFT$(O$,6):TB$=RIGHT$(O$,4):GOSUB675
565 LINEINPUT#5,O$:IFINSTR(O$,"<")THENZD$=O$:GOTO560ELSEGOSUB430
570 IFEOF(5)THENCLOSE5:IFZA$<>"ALL"THENO$="*** PLEASE KILL YOUR MAIL WITH THE 'K' CMD BEFORE YOU DISCONNECT ***":GOSUB430:RD=0:RETURNELSERD=0:RETURN
575 GOTO565
580 CLS:INPUT"Kill Your Mail";ZE$:IFZE$="N"ORZE$="n"THENINPUT"Kill Whose";ZD$:GOSUB850:ZC$=ZX$:ZX$="":U=1ELSEZC$=CA$:U=1
585 MD=0:KILLZC$+".DO":GOSUB805:GOSUB880:GOSUB905:GOSUB320:GOTO30
590 ZD$=MID$(Z$,4,6):Z$=Z$+" < "+ZC$:GOTO615
595 ZD$=MID$(Z$,3,6):Z$=Z$+" < "+ZC$:GOTO615
600 IFINSTR(Z$,"<")=0THEN590
605 IFINSTR(Z$,"@")=0THEN610ELSEZD$=MID$(Z$,4,INSTR(Z$,"@")-5):GOTO615
610 ZD$=MID$(Z$,4,INSTR(Z$,"<")-5)
615 S=1:OPENZD$+".DO"FORAPPENDAS4:PRINT#4,Z$:PRINT#4,DA$" "TI$:IFMFTHENZ$="":COMON:GOTO50
620 COMON:O$="Enter Message; Enter a CTRL-Z to end your message ON A SEPARATE LINE:":GOSUB430:Z$="":GOTO55
625 CLOSE4:OPEN"MESLOG.DO"FORAPPENDAS4:GOSUB850:ZD$=ZX$:ZX$="":PRINT#4,ZD$:CLOSE4:MS=MS+1:GOSUB910
630 IFMF=1THENRETURNELSEO$="*** DONE":GOSUB430:RETURN
635 IFMFTHEN655ELSEO$="Hello "+N$+", Welcome to the "+CA$+" MBX in "+T$:GOSUB430
640 O$=AU$:GOSUB430:O$="H for HELP, I For System Info; There are"+STR$(MS)+" Msgs On the System":GOSUB430
645 O$="If you have never used this MBX before, type 'H' ":GOSUB430:O$="All commands are followed by a 'carrage return'
650 GOSUB430:RETURN
655 IFFRE(0)<1000THENO$=" *** CAUTION - THE MEMORY IS FULL..PLEASE DO NOT ATTEMPT TO LEAVE ANY MESSAGES ***":GOSUB430
660 GOSUB70:O$=ZC$+" de "+CA$+" at "+TI$+" PST on "+DA$+" B,H,I,K,R,S,T,U >":GOSUB430:IFMFTHEN665ELSERETURN
665 O$="*":GOSUB430:O$="*":GOSUB430:RETURN
670 FORI=1TO500:NEXT:RETURN
675 IFINSTR(ZD$,"@")=0THEN685
680 O$=" TR "+" TO "+" @ BBS "+" From"+" Date "+" Time":GOSUB430:O$=" "+ZD$+" "+DB$+" "+TB$:GOSUB430:RETURN
685 O$=" TR "+" TO "+" From"+" Date "+" Time":GOSUB430:O$=" "+ZD$+" "+DB$+" "+TB$:GOSUB430:RETURN
690 CLS:LINEINPUT"Call sign of Receiver ";ZD$:GOSUB850:ZD$=ZX$:ZX$="":OPENZD$+".DO"FORAPPENDAS4:PRINT#4,"S "+ZD$+" < "+CA$
695 PRINT#4,DA$" "TI$:PRINT"Input Message.../EX to End (ON A BLANK LINE)
700 LINEINPUTI$:IFINSTR(I$,"/EX")>0ORINSTR(I$,"/ex")>0THEN710
705 PRINT#4,I$:GOTO700
710 PRINT#4,CR$:CLOSE4:OPEN"MESLOG.DO"FORAPPENDAS4:GOSUB850:ZD$=ZX$:ZX$="":PRINT#4,ZD$:CLOSE4:PRINT"*** DONE
715 FORI=1TO500:NEXT:MS=MS+1:GOSUB910:U=1:GOSUB870:U=0:GOTO55
720 OPEN"USELOG.DO"FORAPPENDAS4:LC$=ZC$+" AT "+TI$+" ON "+DA$:PRINT#4,LC$:CLOSE4:RETURN
725 RD=1:O$="The command Syntax is:":GOSUB430:O$="B - Bye (DISC) K - Kill Your Mail":GOSUB430
730 O$="H - This HELP File I - System Information":GOSUB430:O$="R - Read YOUR mail":GOSUB430
735 O$="S 'CALL' - Send mail T - Pages "+NA$+" for 30 sec":GOSUB430:O$="U - Index of MBX users":GOSUB430
740 RD=0:RETURN
745 RD=1:O$="(To send mail, type 'S & Call' then )":GOSUB430
750 O$="Example: S W6XYZ ALL ON ONE LINE! You will then be prompted to enter your message, so WAIT.":GOSUB430
755 O$="CAUTION: Your message cannot exceed 800 characters":GOSUB430:RD=0:RETURN
760 RD=1:O$="This MINI-PBBS is run on a 24K TRS80 Model 100...":GOSUB430
765 O$="It was written to work within the memory of the TRS-100 without the need for a disk drive.":GOSUB430
770 O$="It is used primarily to store & retrieve messages... 73's."+NA$+" "+CA$:GOSUB430:RD=0:RETURN
775 COMSTOP:OPEN"MESLOG.DO"FORINPUTAS4
780 LINEINPUT#4,O$:GOSUB790:IFEOF(4)THENCLOSE4:GOTO800
785 GOTO780
790 IFINSTR(O$,ZC$)THENRETURN
795 IFINSTR(BE$,O$)THENRETURNELSEBE$=BE$+O$+" ":RETURN
800 O$=BE$:BT$=BE$:COMON:IFLEN(BE$)=<10THENRETURNELSEGOSUB430:BE$="MAIL FOR: ":RETURN
805 MM=0:MS=0:OPEN"MESLOG.DO"FORINPUTAS4:OPEN"MESLO.DO"FOROUTPUTAS5:PRINT#5,CR$
810 LINEINPUT#4,I$:IFEOF(4)ANDI$=ZC$THEN825
815 IFI$=ZC$THENI$="":GOTO810
820 IFI$=CR$THEN825ELSEPRINT#5,I$:MS=MS+1:IFZD$=CA$THENMM=MM+1
825 IFEOF(4)THENCLOSE4,5:KILL"MESLOG.DO":NAME"MESLO.DO"AS"MESLOG.DO":RETURN
830 GOTO810
835 GOSUB670:O$="D":GOSUB430:RETURN
840 GOSUB670:O$="CONV":GOSUB430:RETURN
845 GOSUB670:O$=CHR$(5):GOSUB430:RETURN
850 Z$=ZD$
855 FORX=1TOLEN(Z$):S$=MID$(Z$,X,1):IFASC(S$)>96ANDASC(S$)<123THENS$=CHR$(ASC(S$)-32)
860 ZX$=ZX$+S$:NEXT:RETURN
865 IFB=0THEN870ELSE885
870 ZC$="XXX":BE$="BT MAIL FOR: ":CLS:GOSUB775:GOSUB670
875 IFUTHENZC$="":RETURNELSEO$="BE EV 180":B=1:GOSUB430:ZC$="":GOSUB670:GOTO55
880 OPEN"COM:37N1E"FOROUTPUTAS1:OPEN"COM:37N1E"FORINPUTAS2:RETURN
885 GOSUB670:O$="BE ev 0":GOSUB430:GOSUB670:B=0:GOTO55
890 GOSUB670:O$="conv":GOSUB430:RETURN
895 GOSUB670:GOSUB670:FORI=1TO3:PRINT#1,CHR$(5);:NEXT:GOSUB670:GOSUB670:RETURN
900 GOSUB670:O$="CONOK OFF":GOSUB430:RETURN
905 GOSUB670:O$="CONOK ON":GOSUB430:RETURN
910 IFZD$=CA$THENMM=MM+1:RETURNELSERETURN
915 IFM=0THEN920ELSE925
920 O$="MON ON":GOSUB430:M=1:GOSUB670:GOTO55
925 O$="MON OFF":GOSUB430:M=0:GOSUB670:GOTO55
930 CLS:FILES:FORI=1TO2000:NEXT:GOTO55
935 IFCK=0THENGOSUB900:GOSUB670:CK=1:CK$="OFF":GOTO55
940 IFCK<>0THENGOSUB905:GOSUB670:CK=0:CK$="ON ":GOTO55
945 CLS:PRINT:PRINT"Enter announcement message:":INPUTAU$:PRINTAU$:GOSUB670:GOTO55
950 O$="DAY "+DA$+TI$+RIGHT$(TIME$,2):GOSUB430:GOSUB670:GOTO55
955 O$="Users who check into this MBX:":GOSUB430:RESTORE
960 READZF$,N$,MF:IFZF$="END"THENRETURN
965 O$=N$+"-"+ZF$:GOSUB430:GOTO960